[Linux] Flex와 Bison

 

이 글은 flex & bison 책의 예제코드를 실행하는데 도움이 되기 위해 작성했습니다.

Flex와 Bison의 문법에 대한 설명이 없으므로 예제코드를 이해하기 위해서 원문을 먼저 읽어보는 것을 권장드립니다.

 

이 글의 예제코드는 다음 출처에서 가져왔습니다.

Chapter 1. Introducing Flex and Bison

 

Flex

Flex는 토큰을 저장해서 알맞는 enum 타입으로 변환하는 어휘 분석(Lexer)을 위한 도구입니다.

Bison을 사용하면 헤더파일에 %token으로 등록한 토큰들이 enum으로 자동 생성됩니다.

%{
#include "fb1-5.tab.h"
%}

%%

"+" { return ADD; }
"-" { return SUB; }
"*" { return MUL; }
"/" { return DIV; }
"|" { return ABS; }
[0-9]+ { yylval = atoi(yytext); return NUMBER; }
\n { return EOL; } 
[ \t] { /* ignore whitespace */ }
. { printf("Mystery character %c\n", *yytext); }

%%

 

Bison

Bison은 구문 문석(Parser)을 위한 도구입니다.

%token으로 토큰을 지정하면 자동으로 enum이 생성됩니다.

%% section 안에 BNF 표현식과 유사한 Bison 표현식을 지정하면 해당 표현식으로 자동으로 파싱됩니다.

 

Bison은 다음과 같은 함수를 구문 분석기 코드에 생성합니다.

• yyparse() : 주어진 입력을 분석하고 파싱하는 함수입니다.
• yylex() : 입력 문자열에서 토큰을 생성하는 함수입니다.
• yyerror() : 구문 분석 중 발생한 오류를 처리하는 함수 입니다.

yylex()와 yyerror()의 경우 함수에 대한 선언을 상단에 작성해야 컴파일이 가능합니다.

%{
#include <stdio.h>

int yylex();
void yyerror(char *s);
%}

/* declare tokens */
%token NUMBER
%token ADD SUB MUL DIV ABS
%token EOL

%%
calclist: /* nothing */
         | calclist exp EOL { printf("= %d\n", $2); }
         ;
exp: factor
     | exp ADD factor { $$ = $1 + $3; }
     | exp SUB factor { $$ = $1 - $3; }
     ;
factor: term
        | factor MUL term { $$ = $1 * $3; }
        | factor DIV term { $$ = $1 / $3; }
        ;
term: NUMBER
       | ABS term { $$ = $2 >= 0? $2 : - $2; }
       ;

%%

int main(int argc, char **argv)
{
	yyparse();
}

void yyerror(char *s)
{
	fprintf(stderr, "error: %s\n", s);
}

 

Makefile

다음과 같이 Makefile을 작성하면 컴파일이 됩니다.

fb1-5: fb1-5.l fb1-5.y
	bison -d fb1-5.y
	flex fb1-5.l
	cc -o $@ fb1-5.tab.c lex.yy.c -ll